Script: AI talking to the player when frobbed

[MirceaKitsune]

First off thanks to Dragofer and other users who helped with the scripting basics needed to get this done. As a detail for some FM's I plan to make in the future, I wanted to have it possible for friendly AI to be frobbed for idle chatter, causing them to say something random to the player. I first tried with conversation entities but the setup was too ugly and complex, so I decided to do this using one script function. I succeeded with pretty nice results, thus I figured I'd share this for other FM creators to use as well.

The thing I like most is that it only requires one universal function to be added to your map scripts. Every AI can use it with a simple spawnarg and it doesn't require manually setting any sound shaders: It will automatically work on any character! This means you can use it on a pro guard, a builder priest, a noble woman... each will say the appropriate thing when frobbed. This is done with the power of the ai.bark() call which lets you make the AI speak any action defined in their vocal set (universal across all vocal sets).

To get it working you only need to add two spawnargs to your AI, with a third optional one for customization (explained below):

frobable 1
frob_action_script ai_frob
frob_bark ...

frob_bark is optional: If not set the AI will normally greet the player... if alert or having seen evidence of intruders, it will use other lines to inform the player depending on severity. This parameter can be set to the following values to get a custom result:

• "suspicious": The AI always acts as if it has seen indirect evidence of trouble and warns the player.
• "alert": The AI always acts as if it has seen an intruder warns the player.
• "angry": The AI is upset and curses at the player.
• "rambling": The AI rambles random things when talking to the player (idle lines).

Finally here's the script itself. It's pretty tiny, most of the code is for choosing the voice to use. Put it on an AI and let me know if you like the result

void ai_frob(ai self)
{
	if(!self.AI_DEAD && !self.AI_KNOCKEDOUT && self.AI_AlertLevel < 3)
	if(self.isFriend($player1) || self.isNeutral($player1))
	{
		string frob_type = self.getKey("frob_bark");
		string frob_bark;

		// Pick what the AI will say when frobbed
		if(frob_type == "alert")
		{
			frob_bark = "snd_warnSawEnemy";
		}
		else if(frob_type == "suspicious")
		{
			frob_bark = "snd_warnSawEvidence";
		}
		else if(frob_type == "angry")
		{
			frob_bark = "snd_admonish_friend";
		}
		else if(frob_type == "rambling")
		{
			frob_bark = "snd_relaxed";
		}
		else
		{
			if(self.AI_AlertLevel > 2)
				frob_bark = "snd_warnSawEnemy";
			else if(self.AI_AlertLevel > 1)
				frob_bark = "snd_somethingSuspicious";
			else if(self.hasSeenEvidence())
				frob_bark = "snd_warnSawEvidence";
			else
				frob_bark = "snd_greeting_generic";
		}

		float look_time = 1 + sys.random(1);
		self.bark(frob_bark);
		self.lookAt($player1, look_time);
		sys.wait(look_time);
	}
}

ai_frob.script

Edited December 12, 2020 by MirceaKitsune

[MirceaKitsune]

I simplified the code a bit and gave alert / evidence states priority over the normal voice (customized with the frob_bark parameter) while alert state checks were fixed so both levels are within normal bounds. Use whichever version of the script you find most fitting for your FM of course.

void ai_frob(ai self)
{
	if(self.AI_DEAD || self.AI_KNOCKEDOUT || self.AI_AlertLevel > 2 || self.isEnemy($player1))
		return;

	string frob_type = self.getKey("frob_bark");
	string frob_bark;

	if(self.AI_AlertLevel > 1)
	{
		frob_bark = "snd_warnSawEnemy";
	}
	else if(self.AI_AlertLevel > 0)
	{
		frob_bark = "snd_somethingSuspicious";
	}
	else if(self.hasSeenEvidence())
	{
		frob_bark = "snd_warnSawEvidence";
	}
	else
	{
		if(frob_type == "alert")
			frob_bark = "snd_warnSawEnemy";
		else if(frob_type == "suspicious")
			frob_bark = "snd_warnSawEvidence";
		else if(frob_type == "angry")
			frob_bark = "snd_admonish_friend";
		else if(frob_type == "rambling")
			frob_bark = "snd_relaxed";
		else
			frob_bark = "snd_greeting_generic";
	}

	float look_time = 1 + sys.random(1);
	self.bark(frob_bark);
	self.lookAt($player1, look_time);
	sys.wait(look_time);
}

ai_frob.script